Использовать Google поиск

Установка Windows 8.1 на планшет Asus T100TA с использованием WIMBoot

05.05.2014

Помните сведения о новых возможностях Windows 8.1, благодаря которым новая версия операционной системы Microsoft может храниться на диске компьютера или флэш-памяти планшета в сжатом виде в специальном разделе, что позволяет заметно сэкономить место на тех устройствах, которые имеют ограниченный объем встроенной памяти?

Новая функция называется WIMBoot и позволяет иметь до 12 ГБ свободного на планшетах, оснащенных 16 ГБ встроенной памяти. Наличие подобной возможности особенно порадует владельцев тех планшетов, которые с завода будут иметь новую версию Windows 8.1 с поддержкой WIMBoot. А как быть тем, у кого Windows на планшете установлена по-старому? К счастью, владельцы подобных устройств могут переустановить Windows заново, освободив при этом несколько гигабайт полезного места.

Как это можно сделать я сегодня расскажу вам на примере инструкции по установке Windows 8.1 на планшет Asus Transformer Book T100TA, опубликованной недавно на польском сайте avisek.pl.

Идея метода заключается в том, чтобы использовать для установки Windows раздел восстановления, в котором будут храниться образы системы.

Инструкция по установке Windows 8.1 на планшет Asus T100TA с использованием WIMBoot

Внимание! После выполнения данной процедуры, вы получите «чистую» версию Windows и все ваши данные, а также программы, имевшиеся на планшете будут утеряны!

Требования:

• Планшет Asus T100TA

• Образ Windows 8.1: Win8.1_WIMBootENv1.iso

• Программа Rufus для записи образа на флэшку

• USB флэш-накопитель, объемом не менее 8 ГБ

Итак, начнем:

Внимание! Описанная ниже процедура подходит для планшета с 32 ГБ встроенной памяти. Для 64-гигабайтной версии Transformer Book T100TA, вам нужно внести изменения в файл CreatePartitions-WIMBoot.txt (пункт 6 инструкции), изменив размер Windows раздела в строке «create partition primary size=25500» на большее, соответствующее вашему случаю.

1. Подключите USB флэш накопитель, запустите программу Rufus, выберите в ней скачанный ранее ISO файл (поле «ISO Image») с образом Windows 8.1 и нажмите на «Start»:

2. По окончанию работы программы вы получите загрузочный диск с Windows PE

3. Выключите свой Asus T100TA полностью, подключите флэшку к планшету и загрузитесь с неё (в меню загрузки можно попасть путем нажатия клавиши «Esc» при старте системы).

4. После загрузки Windows PE вы увидите окно командной строки

5. В окне командной строки перейдите на флеш-накопитель, выполнив команду

где d: - это имя USB диска

6. Запустите файл Partitioning-WIMBoot.bat, просто набрав его имя в окне командной строки. В результате его выполнения, внутренняя память планшета будет переразбита на разделы и все имеющиеся там ранее данные и программы будут уничтожены.

Для справки: содержимое файла Partitioning-WIMBoot.bat:

diskpart /s CreatePartitions-WIMBoot.txt

Содержимое сценария CreatePartitions-WIMBoot.txt:

rem == Diskpart /s CreatePartitions-WIMBoot.txt ==

rem == These commands set up the hard drive partitions

rem for WIMBoot.

rem

rem Adjust the partition sizes to fill the drive

rem as necessary. ==

select disk 0

clean

convert gpt

rem == 1. System partition (ESP) ===================

create partition efi size=100

format quick fs=fat32 label="System"

rem == 2. Microsoft Reserved (MSR) partition =======

create partition msr size=128

rem == 3. Windows partition ========================

create partition primary size=25500

rem shrink minimum=10000

format quick fs=ntfs label="Windows"

assign letter=c

rem === 4. Images partition ========================

create partition primary

format quick fs=ntfs label="Images"

assign letter=m

set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"

gpt attributes=0x8000000000000001

list volume

exit

7. Запустите в окне командной строки файл Layout-WIMBoot.bat, который скопирует необходимые для установки Windows файлы с USB диска во встроенную память планшета, что займет некоторое время.

8. По окончании процедуры копирования наберите команду exit

Ваш планшет перезагрузится, после чего на нем будет установлена Windows 8.1 с использованием WIMboot.

На запрос кода активации ответьте отменой: узнать код вы можете позже, с помощью программы pkeyui.exe, расположенной на установочном флэш-диске, которая считает его из BIOS вашего планшета (опция MSDM KEY).